Excel Data Entry Form VBA: सिंगल क्लिक में ऑटोमैटिक डेटा सेव करना सीखें!

Kunal

22 hours ago

नमस्ते दोस्तों! The Office Tutorials में आपका स्वागत है। अगर आप एक्सेल में मैनुअल डेटा एंट्री कर-करके थक चुके हैं, तो आज हम इस ट्यूटोरियल की सहायता से सीखेंगे की कैसे अपने डाटा एंट्री को आसान बना सकते है। हम इस ट्यूटोरियल मे Excel Data Entry Form VBA के बारे मे जानेंगे।

आज हम सीखेंगे कि Excel में Data Entry Form कैसे बनाएं और VBA कोड की मदद से सिंगल क्लिक में डेटा को दूसरी शीट (Database) में ऑटोमैटिक तरीके से कैसे सेव करें। इस फॉर्म में वैलिडेशन भी लगा है और आप इसे अपने आवश्यकता अनुसार customize भी कर सकते है, यानी अगर कोई फील्ड खाली छूट जाती है, तो एक्सेल आपको एक एरर मैसेज भी देगा!

आप नीचे दिए गए हमारे वीडियो ट्यूटोरियल को देखकर भी इसे आसानी से समझ सकते हैं:

चलिए, इस Excel Data Entry Form को बिल्कुल शुरुआत से स्टेप-बाइ-स्टेप बनाते हैं!

स्टेप 1: एक्सेल शीट्स (Sheets) तैयार करना

सबसे पहले, आपको अपनी एक्सेल वर्कबुक में दो शीट्स बनानी होंगी:

Sheet1 (डेटा शीट): यह हमारा डेटाबेस होगा। इसमें पहली रो (Row 1) में हेडिंग्स टाइप करें: Emp ID, Name, Department, City, Salary. सारा सेव किया हुआ डेटा यहीं आकर ऑटोमैटिक स्टोर होगा।
Sheet2 (फॉर्म शीट): यहाँ हम अपना फॉर्म डिज़ाइन करेंगे। सेल A2 से A5 तक क्रमशः Name, Department, City, और Salary लिखें और उनके सामने वाले सेल्स (B2 से B5) को इनपुट के लिए खाली छोड़ दें। इसे थोड़ा कलर और बॉर्डर देकर एक बेहतरीन फॉर्म का लुक दें।

स्टेप 2: ‘Add Employee’ बटन लगाना

डेटा सबमिट करने के लिए हमें एक बटन की आवश्यकता होगी:

एक्सेल रिबन में Developer Tab पर जाएँ (अगर यह नहीं दिख रहा है, तो रिबन पर राइट-क्लिक करके ‘Customize the Ribbon’ से इसे इनेबल करें)।
Insert पर क्लिक करें और Form Controls के अंदर से Button चुनें।
Sheet2 पर कहीं भी माउस से ड्रैग करके बटन ड्रा करें।
जैसे ही आप बटन छोड़ेंगे, ‘Assign Macro’ का डायलॉग बॉक्स खुल जाएगा। इसे अभी के लिए बंद (Cancel) कर दें।
बटन पर राइट-क्लिक करके Edit Text चुनें और इसका नाम बदलकर “Add Employee” रख दें।

स्टेप 3: VBA कोड ऐड करना

यही वह मैजिक कोड है जो आपके डेटा को फॉर्म से उठाकर डेटाबेस शीट में सही जगह पर पेस्ट करेगा और ऑटोमैटिक एम्प्लॉई ID जनरेट करेगा:

Developer Tab में जाकर Visual Basic पर क्लिक करें (या ALT + F11 दबाएं)।
ऊपर मेनू से Insert > Module पर क्लिक करें।
नीचे दिए गए पूरे कोड को कॉपी करें और उस खाली मॉड्यूल विंडो में पेस्ट कर दें:

Sub AddEmployeeData()

    Dim wsData As Worksheet
    Dim wsForm As Worksheet
    Dim lastRow As Long
    Dim newID As String
    Dim lastIDNum As Long

    ' Define worksheets
    Set wsData = ThisWorkbook.Sheets("Sheet1")
    Set wsForm = ThisWorkbook.Sheets("Sheet2")

    ' Validation: All fields must be filled
    If wsForm.Range("B2").Value = "" Or _
       wsForm.Range("B3").Value = "" Or _
       wsForm.Range("B4").Value = "" Or _
       wsForm.Range("B5").Value = "" Then
       
        MsgBox "Please fill all fields before adding data!", vbExclamation
        Exit Sub
        
    End If

    ' Find last row
    lastRow = wsData.Cells(wsData.Rows.Count, "A").End(xlUp).Row

    ' Extract last Emp ID number
    If lastRow > 1 Then
        lastIDNum = CLng(Mid(wsData.Cells(lastRow, 1).Value, 2))
    Else
        lastIDNum = 0
    End If

    ' Generate new Emp ID
    newID = "E" & Format(lastIDNum + 1, "000")

    ' Insert data into Sheet1
    wsData.Cells(lastRow + 1, 1).Value = newID
    wsData.Cells(lastRow + 1, 2).Value = wsForm.Range("B2").Value
    wsData.Cells(lastRow + 1, 3).Value = wsForm.Range("B3").Value
    wsData.Cells(lastRow + 1, 4).Value = wsForm.Range("B4").Value
    wsData.Cells(lastRow + 1, 5).Value = wsForm.Range("B5").Value

    ' Clear form fields
    wsForm.Range("B2:B5").ClearContents

    MsgBox "Employee data added successfully!", vbInformation

End Sub

पेस्ट करने के बाद VBA एडिटर को क्लोज़ (कट) कर दें!

आप अगर चाहते है की VBA कोड ना लिखूँ तो आप simply माइक्रो भी रिकार्ड कर सकते है।

यह भी सीखें: Excel में Option Button से Data Sort कैसे करें? – Dynamic Sorting Trick

स्टेप 4: बटन में मैक्रो (Macro) असाइन करना

अब हमें अपने बटन को यह बताना है कि क्लिक होने पर कौन सा कोड रन करना है:

अपने “Add Employee” बटन पर राइट-क्लिक करें।
Assign Macro… पर क्लिक करें।
लिस्ट में से AddEmployeeData को सिलेक्ट करें और OK कर दें।

स्टेप 5: अपने फॉर्म की टेस्टिंग करें

बधाई हो! आपका ऑटोमेटेड डेटा एंट्री फॉर्म तैयार है। इसे टेस्ट करके देखते हैं:

एरर टेस्टिंग (Error Testing): फॉर्म को खाली रखें और बटन पर क्लिक करें। आपको तुरंत एक एरर मैसेज आएगा: “Please fill all fields before adding data!”
डेटा एंट्री टेस्टिंग: अब फॉर्म में नाम, विभाग, शहर और सैलरी भरें और बटन पर क्लिक करें। आपको “Success” का मैसेज मिलेगा।
Sheet1 में जाकर देखें, आपका डेटा ऑटोमैटिक E001 जैसी ID के साथ ऐड हो चुका होगा। फॉर्म खाली हो जाएगा और अगले एंट्री के लिए तैयार रहेगा।

प्रैक्टिस फाइल डाउनलोड करें (Download Free Practice File)

अगर आपको इसे बनाने में कोई परेशानी आ रही है, तो आप हमारी रेडीमेड प्रैक्टिस एक्सेल फाइल नीचे दिए गए लिंक से बिलकुल फ्री में डाउनलोड कर सकते हैं:

Download Excel Practice File

प्रो टिप: आप इस फॉर्म को और भी एडवांस बना सकते हैं। जैसे कि सैलरी वाले सेक्शन में सिर्फ नंबर्स ही टाइप हों (Text ना टाइप हो पाए), इसे डेटा वैलिडेशन (Data Validation) या थोड़े से और VBA कोड एडिटिंग से किया जा सकता है। अगर आप चाहते हैं कि मैं इस पर भी एक डेडिकेटेड ट्यूटोरियल बनाऊं, तो मुझे कमेंट करके जरूर बताएं!

अगर आपको यह ट्यूटोरियल मददगार लगा हो, तो इस पोस्ट को अपने दोस्तों के साथ शेयर करें और हमारे YouTube Channel और Facebook Page को फॉलो करना न भूलें!